#-----------------------------------------------------------------------
# ANIMATION UTILITY

script, odd frame, begin
  exit returning((ticks ,mod, 2) == 1)
end

script, load anim from collection, sl, collection, group=0, frame=0, begin
  if(anim container == none) then(
    anim container := create container(0, 0)
    set slice visible(anim container, false)
  )
  variable(col, c)
  free anim collection(sl)
  col := load slice collection(collection)
  c := first child(col)
  set parent(c, anim container)
  set anim collection(sl, c)
  normalize anim groups(c)
  load anim group(sl, group, frame)
end

script, free anim collection, sl, begin
  put back anim frame(sl)
  variable(c)
  c := get anim collection(sl)
  if(c) then(
    free slice(c)
    set anim collection(sl, 0)
  )
end

script, normalize anim groups, c, begin
  variable(gr, fr, w, h)
  gr := first child(c)
  while(gr) do(
    fr := first child(gr)
    if(fr == none) then(
      $0="Warning:", trace(0)
      trace value(child count(gr))
    )else(
      w := slice width(fr)
      h := slice height(fr)
      fr := next sibling(fr)
      while(fr) do(
        if (w <> slice width(fr)) then(
          $0="corrected frame width "
          append number(0, slice width(fr))
          $0+" to "
          append number(0, w)
          trace(0)
          set slice width(fr, w)
        )
        if (h <> slice height(fr)) then(
          $0="corrected frame height "
          append number(0, slice height(fr))
          $0+" to "
          append number(0, h)
          trace(0)
          set slice height(fr, h)
        )
        fr := next sibling(fr)
      )
    )
    gr := next sibling(gr)
  )
end

script, load anim group, sl, group, frame=-1, begin
  if(group <> get anim group(sl)) then(
    put back anim frame(sl)
    set anim group(sl, group)
    if(frame == -1) then(frame := 0)
    set anim frame state(sl, 0)
  )
  if(frame >= 0) then(
    load anim frame(sl, frame)
  )
end

script, load anim frame, sl, frame, begin
  if(frame == get anim frame(sl)) then(
    exit script
  )
  put back anim frame(sl)
  set anim frame(sl, frame)
  set anim frame state(sl, 0)
  variable(c, group)
  c := get anim collection(sl)
  group := get anim group(sl)
  variable(gr, fr)
  gr := slice child(c, group)
  fr := slice child(gr, frame)
  # save old bottom
  variable(old bottom)
  old bottom := slice edge y(sl, edge:bottom)
  # copy width and height
  set slice width(sl, slice width(fr))
  set slice height(sl, slice height(fr))
  # restore old bottom
  set slice edge y(sl, edge:bottom, old bottom)
  # move over frame contents
  if(child count(sl) <> 1) then(
      $0="oops, trying to set frame, expected only metadata, but found "
      append number(0, child count(sl))
      $0+" children there"
      trace(0)
  )
  variable(ch)
  ch := first child(fr)
  while(ch) do(
    set parent(ch, sl)
    ch := first child(fr)
  )
  
end

script, put back anim frame, sl, begin
  variable(c, group, frame)
  frame := get anim frame(sl)
  if(frame >= 0) then(
    c := get anim collection(sl)
    group := get anim group(sl)
    variable(gr, fr)
    gr := slice child(c, group)
    fr := slice child(gr, frame)
    variable(ch)
    if(child count(fr) <> 0) then(
      $0="oops, trying to put back frame, but there are already "
      append number(0, child count(fr))
      $0+" children there"
      trace(0)
    )
    while(child count(sl) >> 1) do(
      ch := slice child(sl, 1)
      set parent(ch, fr)
    )
    set anim frame(sl, -1)
  )
end

script, mod frame, sl, n, begin
  variable(st)
  st := advance frame state(sl)
  if(st << 0) then(exit returning(false))
  exit returning((st ,mod, n) == 0)
end

script, advance frame state, sl, begin
  variable(st)
  st := get anim frame state(sl)
  if(st >= 0) then(
    set anim frame state(sl, st + 1)
  )
  exit returning(get anim frame state(sl))
end

script, cycle frame, sl, begin
  variable(c, group, frame, gr)
  c := get anim collection(sl)
  group := get anim group(sl)
  frame := get anim frame(sl)
  gr := slice child(c, group)
  frame += 1
  if(frame >= child count(gr)) then(frame := 0)
  load anim frame(sl, frame)
end

script, frame to last, sl, begin
  variable(c, group, frame, gr, st)
  st := get anim frame state(sl)
  if(st == -1) then(exit script)
  c := get anim collection(sl)
  group := get anim group(sl)
  frame := get anim frame(sl)
  gr := slice child(c, group)
  frame += 1
  if(frame >= child count(gr)) then(
    set anim frame state(sl, -1)
    exit script
  )
  load anim frame(sl, frame)
end

#-----------------------------------------------------------------------
# PLAYER ANIMATION

script, animate player, sl, begin
  variable(fx, fy, d, cr, atk)

  d := (get direction(sl) + 1) / 2
  cr := get crouching(sl)

  atk := get attacking(sl)
  if(atk >> 0) then(
    if(cr) then(
      load anim group(sl, 14 + d)
    )else(
      load anim group(sl, 12 + d)
    )
    if(mod frame(sl, 2)) then(frame to last(sl))
    set attacking(sl, atk -- 1)
    exit script
  )

  fx := get force x(sl)
  fy := get force y(sl)

  if(cr) then(
    # crouching
    if(fx == 0) then(
      load anim group(sl, 4 + d)
      # FIXME: this is too complicated, and doesn't work perfectly
      if(get transition anim needed(sl)) then(
        if(mod frame(sl, 3)) then(
          frame to last(sl)
          if(get anim frame state(sl) == -1) then(
            set transition anim needed(sl, false)
          )
        )
      )else(
        frame to last(sl)
      )
    )else(
      # crawling
      load anim group(sl, 6 + d)
      if(odd frame) then(
        cycle frame(sl)
      )
    )
  )else(
    if(get touching floor(sl)) then(
      # standing/walking
      if(fx == 0) then(
        load anim group(sl, 0 + d)
      )else(
        load anim group(sl, 2 + d)
        if(odd frame) then(
          cycle frame(sl)
        )
      )
    )else(
      # Jumping
      if(fy << 0) then(
        load anim group(sl, 8 + d)
      )else(
        load anim group(sl, 10 + d)
      )
      if(mod frame(sl, 3)) then(frame to last(sl))
    )
  )
end