# Chain Mail Bikini
# (C)Copyright 2012 James Paige
#
# OHRRPGCE Sidescroller scripts adapted from Bell of Chaos
#-----------------------------------------------------------------------

include, plotscr.hsd
include, scancode.hsi

#-----------------------------------------------------------------------

include, globals.hsi
include, playercontrols.hsi
include, metadata.hsi
include, maps.hsi
include, collisions.hsi
include, animate.hsi
include, camera.hsi
include, utility.hsi

#-----------------------------------------------------------------------

plotscript, new game, begin
  main
end

plotscript, load game, begin
  main
end

#-----------------------------------------------------------------------

script, init, begin
  suspend player
  ticks := second
  load map(0)
  player := create player
end

script, main, begin
  init
  while(true) do(
    do updates
    do collisions
    do forces
    do removals
    update camera(player)
    wait(1)
    ticks += 1
  )
end

#-----------------------------------------------------------------------
# PLAYER

script, create player, begin
  variable(sl)
  sl := create container(0, 0)
  set parent(sl, active)
  init metadata(sl)
  load anim from collection(sl, 0, 0)

  set walk max(sl, 8)
  set can crouch(sl, true)

  set update callback(sl, @player update)
  #set touch callback(sl, @harmed by monsters)

  exit returning(sl)
end

script, player update, sl, begin
  player keys(sl)
  force of gravity(sl)
  if(pushing left == 0 && pushing right == 0 && pushing down == 0 && pushing up == 0) then(extra friction(sl))
  animate player(sl)
end

#-----------------------------------------------------------------------
# ACTIONS

script, jump or dash slide, sl, begin
  if(get crouching(sl)) then(
    if(abs(get force x(sl)) >> 4) then(
      #dive jump if already sliding
      jump(sl)
      push force x(sl, 20 * get direction(sl))
    )else(
      dash slide(sl)
    )
  )else(
    jump(sl)
  )
end

script, jump, sl, begin
  push force y(sl, -17)
end

script, dash slide, sl, begin
  if(get touching floor(sl) && get crouching(sl)) then(
    push force x(sl, 20 * get direction(sl))
    set antifriction(sl, 4)
  )
end

#-----------------------------------------------------------------------
# TOUCH CALLBACKS


#-----------------------------------------------------------------------
# UPDATES

script, do updates, begin
  for each child(active, @run update callback)
end

script, do collisions, begin
  for each child(active, @pre check collisions)
  for each child(active, @check collisions)
end

script, do forces, begin
  for each child(active, @apply force)
end

script, do removals, begin
  variable(sl, delete)
  sl := first child(active)
  while(sl) do(
    if(get remove me(sl)) then(delete := sl)
    sl := next sibling(sl)
    if(delete) then(
      free slice(delete)
      delete := 0
    )
  )
end

#-----------------------------------------------------------------------
# FORCE

script, apply force, sl, begin
  variable(fx, fy, d)
  fx := get force x(sl)
  fy := get force y(sl)
  d := get direction(sl)
  if(fx << 0) then(d := -1)
  if(fx >> 0) then(d := 1)
  set direction(sl, d)
  if(get immobile(sl)) then(exit script)
  set slice y(sl, slice y(sl) + fy)
  set slice x(sl, slice x(sl) + fx)
end

#-----------------------------------------------------------------------
# PHYSICS

script, force of gravity, sl, begin
  push force y(sl, gravity force)
end

script, force of friction, sl, begin
  variable(force, crouch, friction, antifriction)
  antifriction := get antifriction(sl)
  if(antifriction >> 0) then(
    set antifriction(sl, antifriction -- 1)
    exit script
  )
  force := get force x(sl)
  friction := 1
  crouch := get crouching(sl)
  if(crouch && abs(force) >= 4) then(
    friction += 2
  )
  if(force >> 0) then(force -= friction, if(force << 0) then(force := 0))
  if(force << 0) then(force += friction, if(force >> 0) then(force := 0))
  set force x(sl, force)
end

script, extra friction, sl, friction=1, begin
  variable(force, antifriction)
  antifriction := get antifriction(sl)
  if(antifriction >> 0) then(
    exit script
  )
  force := get force x(sl)
  if(force >> 0) then(force -= friction, if(force << 0) then(force := 0))
  if(force << 0) then(force += friction, if(force >> 0) then(force := 0))
  set force x(sl, force)
end

#-----------------------------------------------------------------------