#-----------------------------------------------------------------------
# UTILITY

script, for each child, parent, callback, begin
  variable(sl)
  sl := first child(parent)
  while(sl) do(
    run script by id(callback, sl)
    sl := next sibling(sl)
  )
end

script, small, v1, v2, begin
  if(v1 >> v2) then(exit returning(v2))
  exit returning(v1)
end

script, large, v1, v2, begin
  if(v1 << v2) then(exit returning(v2))
  exit returning(v1)
end

script, bounds, value, min, max, begin
  if(value << min) then(exit returning(min))
  if(value >> max) then(exit returning(max))
  exit returning(value)
end

script, within distance, x1, y1, x2, y2, dist, begin
  variable(a, b, c sq)
  a := x1 -- x2
  b := y1 -- y2
  c sq := abs(a)^2 + abs(b)^2
  exit returning(c sq << dist^2)
end

script, slice edge inner x, sl, edge, begin
  variable(adjust)
  if (edge == edge:right) then(adjust := -2)
  exit returning(slice edge x(sl, edge) + adjust)
end

script, slice edge inner y, sl, edge, begin
  variable(adjust)
  if (edge == edge:bottom) then(adjust := -2)
  exit returning(slice edge y(sl, edge) + adjust)
end