include, plotscr.hsd
include, scancode.hsi
include, ganovel.hsi

global variable(1, anim callback table)
global variable(2, total ticks)

define constant(18, second)

########################################################################

plotscript, The Great American Novel, begin
  initialize
  Joe walked along the levy
  chopping the lake into endless lines
  reddening the clouds that boiled away
  $0="THE END"
  show string(0)
end

script, initialize, begin
  suspend player
  anim callback table := create container(0,0)
  set slice visible(anim callback table, false)
end

script, Joe walked along the levy, begin

  variable(stage)
  stage :=  load slice collection(1)

  variable(Joe)
  Joe := lookup slice(sli:Joe, stage)
  add anim callback(Joe, @toggle frame)

  variable(sky)
  sky := lookup slice(sli:Sky, stage)
  move slice by(sky, -320, 0, 104)
  
  variable(front trees, back trees)
  front trees := lookup slice(sli:front trees, stage)
  move slice by(front trees, 20, 0, 104)
  back trees := lookup slice(sli:back trees, stage)
  move slice by(back trees, 10, 0, 104)
  
  variable(i)
  for(i, 0, 3) do(
    move slice by(Joe, -15, -5, 16)
    w(Joe)
    move slice by(Joe, -15, 5, 10)
    w(Joe)
  )
  
  remove anim callback(Joe)
  free slice(stage)
end

script, chopping the lake into endless lines, begin
  variable(stage)
  stage := load slice collection(2)
  
  variable(water)
  water := lookup slice(sli:water)
  move slice by(water, 160, 0, second * 3)
  w(water)
  
  free slice(stage)
end

script, reddening the clouds that boiled away, begin
  variable(stage)
  stage := load slice collection(3)
  
  variable(sun)
  sun := lookup slice(sli:Sun, stage)
  move slice to(sun, slice x(sun), 110, second * 6)
  add anim callback(sun, @darken slowly)
  
  variable(i, sky)
  sky := lookup slice(sli:Sky, stage)
  for(i, 0, 2) do(
    wt(21)
    replace backdrop sprite(sky, get sprite set number(sky) + 1)
  )
  w(sun)
  
  remove anim callback(sun)
  free slice(stage)
  wait(1)
  reset palette
  update palette
end

########################################################################

script, toggle frame, sl, begin
  variable(num)
  num := get sprite set number(sl)
  num := num, xor, (total ticks, mod, 2)
  replace backdrop sprite(sl, num)
end

script, darken slowly, sl, begin
  # does not actually use the slice
  if(total ticks, mod, 12 == 0) then(
    tweak palette(-1, -1, -1)
    update palette
  )
end

########################################################################

script, wt, ticks, begin
  variable(i)
  for(i, 1, ticks) do(
    wait(1)
    wait common
  )
end

script, w, sl, begin
  while(slice is moving(sl)) do(
    wait(1)
    wait common
  )
end

script, wait common, begin
  run anim callbacks
  total ticks += 1
  if(key is pressed(key:ESC)) then(
    game over
  )
end

script, add anim callback, sl, callback, begin
  variable(cb)
  cb := create container(sl, callback)
  set parent(cb, anim callback table)
end

script, remove anim callback, sl to remove, begin
  variable(cb, sl, remove)
  cb := first child(anim callback table)
  while(cb) do(
    sl := slice width(cb)
    if(sl == sl to remove) then(
      remove := cb
    )
    cb := next sibling(cb)
    free slice(remove)
    remove := none
  )
end

script, run anim callbacks, begin
  variable(cb, sl, callback)
  cb := first child(anim callback table)
  while(cb) do(
    sl := slice width(cb)
    callback := slice height(cb)
    run script by id(callback, sl)
    cb := next sibling(cb)
  )
end

########################################################################