script, golem animate, sl, begin
  apply frame set(sl, 0)
  variable(pic)
  pic := get pic(sl)
  variable(fx)
  fx := get force x(sl)
  if(fx <> 0) then(
    oscillate frame(pic, 0, 2, 2)
  )
  damage animate(sl, 0, 3, 4, 5)
end

script, pouncer animate, sl, begin
  apply frame set(sl, 0)
  variable(pic)
  pic := get pic(sl)
  variable(fx)
  fx := get force x(sl)
  if(fx <> 0) then(
    oscillate frame(pic, 0, 2, 2)
  )
  damage animate(sl, 0, 3, 4, 5)
end

script, pouncer pounce animate, sl, begin
  apply frame set(sl, 1)
  variable(pic)
  pic := get pic(sl)
  variable(age)
  age := get age(sl)
  if(age > second) then(
    # Pounce
    loop frame(pic, 2, 4, 1)
  )else(
    # Coil
    loop frame(pic, 0, 1, 1)
  )
  
  damage animate(sl, 0, 3, 4, 5)
end

script, diver animate, sl, begin
  variable(fy)
  fy := get force y(sl)
  variable(pic)
  pic := get pic(sl)
  if(fy > 5) then(
    loop frame(pic, 6, 7)
  )else(
    oscillate frame(pic, 0, 2, small(abs(fy), 3))
  )
  
  damage animate(sl, 0, 3, 4, 5)
end

script, carrot demon walk animate, sl, begin
  apply frame set(sl, 0)
  variable(pic)
  pic := get pic(sl)
  variable(fx)
  fx := get force x(sl)
  if(fx <> 0) then(
    oscillate frame(pic, 0, 2, 2)
  )else(
    clamp frame(pic, 0, 2)
  )
  if(not(get touching floor(sl))) then(
    set sprite frame(pic, 4)
  )
  if(guarding animate(sl, 0, 4)) then(
    damage animate(sl, 1, 3, 4, 5)
  )
end

script, carrot demon attack animate, sl, begin
  variable(pic)
  pic := get pic(sl)
  apply frame set(sl, 1)
  set sprite frame(pic, 0)
  if(get weapon(sl) == item:rock) then(
    set sprite frame(pic, 2)
  )
  attack animate(sl, 1, 1, 2)
  if(guarding animate(sl, 0, 4)) then(
    damage animate(sl, 1, 3, 4, 5)
  )
end

script, carrot demon weak animate, sl, begin
  variable(pic)
  pic := get pic(sl)
  apply frame set(sl, 1)
  set sprite frame(pic, 2)
  damage animate(sl, 1, 3, 4, 5)
end

script, prancing bulb walk animate, sl, begin
  variable(fx)
  fx := get force x(sl)
  variable(pic)
  pic := get pic(sl)
  if(fx <> 0) then(oscillate frame(pic, 0, 2, 2))
  damage animate(sl, 0, 3, 4, 5)
end

script, prancing flower animate, sl, begin
  variable(pic)
  pic := get pic(sl)
  set sprite frame(pic, 6 -- large(get hp(sl), 0) / 2)
  if(being damaged(sl)) then(
    if(not(is alive(sl))) then(
      frame to last(pic, 0, 6)
    )
  )
end

script, death tulip root animate, sl, begin
  if(alternate(sl, second * 2 / 3)) then(
    loop frame(get pic(sl), 0, 1, 2)
  )
end

script, death tulip stalk animate, sl, begin
  variable(a, xd, yd, pic)
  a := get attached to(sl)
  if(a) then(
    xd := slice x(sl) -- slice x(a)
    yd := slice y(sl) -- slice y(a)
    set frame by slope(sl, xd, yd)
  )
end

script, death tulip flower animate, sl, begin
  variable(a, xd, yd, pic)
  a := get attached to(sl)
  if(a) then(
    pic := get pic(sl)
    xd := slice x(sl) -- slice x(a)
    yd := slice y(sl) -- slice y(a)
    if(xd < 0) then(set direction(sl, -1))
    if(xd > 0) then(set direction(sl, 1))
    xd := abs(xd)
    if(yd < 0) then(
      if(abs(yd) > xd) then(loop frame(pic, 0, 1, 2), exit script)
      loop frame(pic, 2, 3, 2), exit script
    )else(
      if(abs(yd) < xd) then(loop frame(pic, 4, 5, 2), exit script)
      loop frame(pic, 6, 7, 2), exit script
    )
  )
end

script, caterpillar animate, sl, begin
  variable(fx)
  fx := get force x(sl)
  if(fx <> 0) then(
    loop frame(get pic(sl), 0, 2, 2)
  )
  death dissolve(sl, dissolve:melt)
end

script, caterpillar segment animate, sl, begin
  variable(a)
  a := get attached to(sl)
  if(a) then(
    variable(fx, fy, pic)
    fx := get force x(a)
    fy := get force y(a)
    pic := get pic(sl)
    if(fy < 0) then(
      set sprite frame(pic, 3)
    )else(
      if(fx <> 0) then(
        loop frame(pic, 0, 2, 2)
      )else(
        clamp frame(pic, 0, 2)
      )
    )
    clone damage tick(sl)
    death dissolve(sl, dissolve:melt, a)
  )
end

script, mace dryad animate, sl, begin
  variable(pic, fx)
  pic := get pic(sl)
  apply frame set(sl, 0)
  if(get touching floor(sl)) then(
    fx := get force x(sl)
    if(fx == 0) then(
      set sprite frame(pic, 0)
    )else(
      oscillate frame(pic, 1, 3, 2)
    )
  )else(
    set sprite frame(pic, 4)
  )
end

script, mace dryad attack animate, sl, begin
  # Actually controlled by the mace
end

script, mace dryad mace animate, sl, begin
  variable(a)
  a := get attached to(sl)
  if(a) then(
    set damage tick(sl, get damage tick(a))

    variable(ph, pic)
    ph := get attack phase(a)
    if(ph > 0) then(
      # Swinging Mace
      pic := get pic(a)
      apply frame set(a, 1)
      if(ph <= 1) then(
        set sprite frame(pic, 0)
        apply frame set(sl, 0, 0)
      )else if(ph <= 10) then(
        set sprite frame(pic, 1)
        apply frame set(sl, 0, 4)
      )else if(ph <= 11) then(
        set sprite frame(pic, 0)
        apply frame set(sl, 0, 0)
        create leaf burst(sl, 2)
      )else if(ph <= 12) then(
        set sprite frame(pic, 2)
        apply frame set(sl, 0, 1)
      )else if(ph <= 13) then(
        set sprite frame(pic, 4)
        apply frame set(sl, 0, 2)
      )else if(ph <= 24) then(
        if(ph == 14) then(
          create leaf burst(sl, 2)
        )
        set sprite frame(pic, 5)
        apply frame set(sl, 0, 3)
      )else if(ph <= 25) then(
        set sprite frame(pic, 4)
        apply frame set(sl, 0, 2)
      )else if(ph <= 26) then(
        set sprite frame(pic, 2)
        apply frame set(sl, 0, 1)
      )else(
        set sprite frame(pic, 0)
        apply frame set(sl, 0, 0)
      )
    )else(
      if(get touching floor(a)) then(
        # Standing
        apply frame set(sl, 0, 0)
      )else(
        #jumping
        apply frame set(sl, 0, 1)
      )
    )

    update attachment pos(sl, a)
  )
end

script, plummet bell animate, sl, begin
  variable(fy, pic)
  pic := get pic(sl)
  if(being damaged(sl)) then(
    set sprite frame(pic, 1)
    exit script
  )
  if(get touching ceiling(sl)) then(
    set sprite frame(pic, 0)
  )else(
    fy := get force y(sl)
    if(fy < 0) then(
      oscillate frame(pic, 5, 7, 2)
    )else if(fy >= 4) then(
      loop frame(pic, 2, 4)
    )else(
      if(is p2 controlled(sl)) then(
        oscillate frame(pic, 5, 7, 2)
      )else(
        set sprite frame(pic, 1)
      )
    )
  )
end

script, leaping amaranth animate, sl, begin
  variable(fx, fy, pic)
  pic := get pic(sl)
  if(being damaged(sl)) then(
    set sprite frame(pic, 5)
    exit script
  )
  if(get touching floor(sl)) then(
    fx := get force x(sl)
    if(fx <> 0) then(loop frame(pic, 0, 2, 2))
  )else(
    fy := get force y(sl)
    if(fy < 0) then(
      set sprite frame(pic, 3)
    )else if(fy > 0) then(
      set sprite frame(pic, 4)
    )
  )
end

script, amaranth face animate, sl, begin
  variable(pic)
  pic := get pic(sl)
  if(once every(sl, second)) then(
    set sprite frame(pic, 1)
  )else(
    set sprite frame(pic, 0)
  )
  variable(a)
  a := get attached to(sl)
  if(a) then(
    set damage tick(sl, get damage tick(a))
    if(get attack phase(sl) > 0) then(
      set sprite frame(pic, 2)
    )
  )
end

script, sunflower golem animate, sl, begin
  if(once every(sl, second)) then(
    apply frame set(sl, 1)
  )else(
    apply frame set(sl, 0)
  )
  variable(pic)
  pic := get pic(sl)
  variable(fx)
  fx := get force x(sl)
  if(fx <> 0) then(
    loop frame(pic, 0, 2, 2)
  )
  damage animate(sl, 0, 3, 4, 5)
end

script, spigot wad animate, sl, begin
  if(once every(sl, second / 4)) then(
    set ai toggle(sl, random(0, 1))
  )
  variable(pic, age)
  pic := get pic(sl)
  age := get age(sl)
  if(get ai toggle(sl)) then(
    set sprite frame(pic, age / 2 ,mod, 2)
  )else(
    set sprite frame(pic, age / 5 ,mod, 2)
  )
  damage animate(sl, 0, 2, 3, 4)
end

script, bramblespitter animate, sl, begin
  variable(fx, pic, cr)
  fx := get force x(sl)
  pic := get pic(sl)
  cr := get crouching(sl)
  if(fx <> 0) then(
    if(cr) then(
      loop frame(pic, 3, 4, 2)
    )else(
      loop frame(pic, 0, 2, 2)
    )
  )else(
    # Standing still
    if(cr) then(
      clamp frame(pic, 3, 4)
    )else(
      clamp frame(pic, 0, 2)
    )
  )
end

script, bramblespitter face animate, sl, begin
  variable(pic, ph)
  pic := get pic(sl)
  ph := get attack phase(sl)
  if(ph == 0) then(
    set sprite frame(pic, 0)
  )else if(ph >= 13) then(
    set sprite frame(pic, 3)
  )else(
    loop frame(pic, 1, 2, 1)
  )
  clone damage tick(sl)
end

script, toadstool knight animate, sl, begin
  variable(fx, pic, cr)
  fx := get force x(sl)
  pic := get pic(sl)
  cr := get crouching(sl)
  if(cr) then(
    apply frame set(sl, 1)
    if(fx <> 0) then(
      loop frame(pic, 0, 1, 2)
    )else(
      clamp frame(pic, 0, 1)
    )
  )else(
    apply frame set(sl, 0)
    if(fx <> 0) then(
      loop frame(pic, 1, 4, 2)
    )else(
      set sprite frame(pic, 0)
    )
    if(not(get touching floor(sl))) then(
      if(get force y(sl) < 0) then(
        set sprite frame(pic, 2)
      )else(
        set sprite frame(pic, 4)
      )
    )
    if(being damaged(sl)) then(
      set sprite frame(pic, 5)
    )
    variable(ph)
    ph := get attack phase(sl)
    if(ph > 0) then(
      switch(ph) do(
        case(1, 4) do(set sprite frame(pic, 6))
        case(2, 3) do(set sprite frame(pic, 7))
      )
    )
  )
end

script, toadstool knight face animate, sl, begin
  variable(pic, cr)
  pic := get pic(sl)
  cr := get crouching(sl)
  if(cr) then(
    set sprite frame(pic, 1)
  )else(
    set sprite frame(pic, 0)
  )
  clone damage tick(sl)
end

script, toadstool knight shield animate, sl, begin
  variable(a)
  a := get attached to(sl)
  if(a) then(
    variable(ph)
    ph := get attack phase(a)
    switch(ph) do(
      case(1) do(apply frame set(sl, 0, 1))
      case(2,3) do(apply frame set(sl, 0, 2))
      case(4) do(set remove me(sl, true))
    )
  )
end

script, creeping bellflower animate, sl, begin
  variable(hdir, vdir)
  hdir := get direction(sl)
  vdir := get vertical direction(sl)
  switch(get spatial memory(sl)) do(
    case(up) do(
      apply frame set(sl, 0)
      loop frame(get pic(sl), 4, 7)
    )
    case(down) do(
      apply frame set(sl, 0)
      loop frame(get pic(sl), 0, 3)
    )
    case(left) do(
      set direction(sl, 1)
      if(vdir < 0) then(
        apply frame set(sl, 1)
        loop frame(get pic(sl), 4, 7)
      )else(
        apply frame set(sl, 1)
        loop frame(get pic(sl), 0, 3)
      )
    )
    case(right) do(
      set direction(sl, -1)
      if(vdir < 0) then(
        apply frame set(sl, 1)
        loop frame(get pic(sl), 4, 7)
      )else(
        apply frame set(sl, 1)
        loop frame(get pic(sl), 0, 3)
      )
    )
  )
  death dissolve(sl, dissolve:vapourise)
end

script, ghost orchid legs animate, sl, begin
  variable(cr)
  cr := get crouching(sl)
  if(cr) then(
    frame set to last(sl, 0, 5, 7, 2)
  )else(
    variable(fset)
    fset := get current frame set(sl, 0)
    if(fset >= 5) then(
      frame set to first(sl, 0, 4, 7, 2)
    )else(
      variable(fx)
      fx := get force x(sl)
      if(fx <> 0) then(
        loop frame set(sl, 0, 0, 4, 2)
      )
    )
  )
end

script, ghost orchid abdomen animate, sl, begin
  if(alternate(sl, second)) then(
    loop frame set(sl, 0, 0, 1, 3)
  )else if(alternate(sl, second * 3 / 2)) then(
    if(alternate(sl, second / 5)) then(
       loop frame set(sl, 0, 0, 1, 1)
    )
  )
  clone damage tick(sl)
end

script, ghost orchid tendril animate, sl, begin
  loop frame set(sl, 0, 0, 1, 3)
end

script, ghost orchid tendril attack animate, sl, begin
  if(get age(sl) > second) then(
    if(frame set to last(sl, 0, 1, 7)) then(
      create ghost orchid tendril spike(sl)
      set is enemy(sl, true)
    )
  )
end

script, ghost orchid tendril retract animate, sl, begin
  set is enemy(sl, false)
  if(frame set to first(sl, 0, 1, 7)) then(
    set animation callback(sl, @ghost orchid tendril animate)
    set age(sl, 0)
  )
end

script, ghost orchid tendril spike animate, sl, begin
  if(frame set to last(sl, 0, 0, 1)) then(
    set is enemy(sl, true)
    set animation callback(sl, @ghost orchid tendril spike retract animate)
  )
end

script, ghost orchid tendril spike retract animate, sl, begin
  set is enemy(sl, true)
  if(frame set to first(sl, 0, 0, 1)) then(
    variable(a)
    a := get attached to(sl)
    if(a) then(
      set animation callback(a, @ghost orchid tendril retract animate)
      set age(sl, 0)
    )
    set remove me(sl, true)
  )
end

script, ghost orchid neck animate, sl, begin
  if(get ai toggle(sl)) then(
    # lift head
    frame set to last(sl, 0, 0, 3, 2)
  )else(
    # lower head
    frame set to first(sl, 0, 0, 3, 2)
  )
  clone damage tick(sl)
end

script, ghost orchid node animate, sl, begin
  clone damage tick(sl)
end

script, ghost orchid fringe animate, sl, begin
  variable(legs)
  legs := get secondary attach(sl)
  do ghost orchid fringe animate(sl, legs)
  clone damage tick(sl)
end

script, do ghost orchid fringe animate, sl, legs, begin
  if(legs) then(
    variable(fx,d )
    fx := get force x(legs)
    d := get direction(legs)
    if(fx * d > 0) then(
      loop frame set(sl, 0, 3, 4, 2)
    )else if(fx * d < 0) then(
      loop frame set(sl, 0, 5, 6, 2)
    )else(
      apply frame set(sl, 0)
    )
  )
end

script, ghost orchid wings animate, sl, begin
  clone damage tick(sl)
end

script, ghost orchid torso animate, sl, begin
  loop frame(get pic(sl), 0, 1, 3)
  clone damage tick(sl)
end

script, ghost orchid torso ghost animate, sl, begin
  variable(pic)
  pic := get pic(sl)
  oscillate frame(pic, 2, 4, 3)
  variable(ph)
  ph := get attack phase(sl)
  switch(ph) do(
    case(1,2) do(set sprite frame(pic, 5))
    case(3,4) do(set sprite frame(pic, 6))
    case(5,6) do(set sprite frame(pic, 7))
  )
  clone damage tick(sl)
  if(being damaged(sl)) then(
    set sprite frame(pic, 5)
  )
end

script, flying ghost orchid fringe animate, sl, begin
  variable(a)
  a := get attached to(sl)
  do ghost orchid fringe animate(sl, a)
  clone damage tick(sl)
end

script, flying ghost orchid wings animate, sl, begin
  oscillate frame set(sl, 0, 0, 2, 2)
  clone damage tick(sl)
end

script, hedge bunny animate, sl, begin
  if(get hp(sl) <= 0) then(
    # dying
    frame set to last(sl, 0, 2, 5, 2)
  )
end

script, hedge bunny head animate, sl, begin
  clone damage tick(sl)
  variable(a)
  a := get attached to(sl)
  if(a) then(
    if(get hp(a) <= 0) then(
      # dying
      frame set to last(sl, 0, 2, 5, 2)
    )
  )
end

script, simple spike animate, sl, begin
  if(slice collide(sl, player)) then(
    set animation callback(sl, @simple spike extend animate)
    simple spike extend animate(sl)
    exit script
  )
  apply frame set(sl, 0, 0)
  loop frame(get pic(sl), 0, 7, 2)
end

script, simple spike extend animate, sl, begin
  apply frame set(sl, 0, 1)
  if(frame to last(get pic(sl), 0, 4, 1)) then(
    set animation callback(sl, @simple spike retract animate)
  )
end

script, simple spike retract animate, sl, begin
  apply frame set(sl, 0, 1)
  if(frame to first(get pic(sl), 0, 4, 1)) then(
    set animation callback(sl, @simple spike animate)
  )
end

script, simple spike regrow animate, sl, begin
  apply frame set(sl, 0, 2)
  variable(age)
  age := get age(sl)
  if(age > second * 2) then(
    if(frame to last(get pic(sl), 0, 7, 2)) then(
      set update callback(sl, @simple spike update)
      set animation callback(sl, @simple spike animate)
    )
  )else(
    set sprite frame(get pic(sl), 0)
  )
end


script, rose hip animate, sl, begin
  variable(fx)
  fx := get force x(sl)
  if(fx) then(
    loop frame set(sl, 0, 0, 5, 2)
  )
end

script, rose hip stunned animate, sl, begin
  if(get touching floor(sl)) then(
    frame set to last(sl, 0, 6, 9, 2)
  )else(
    frame set to last(sl, 0, 6, 8, 2)
  )
end

script, pressure plate animate, sl, begin
  frame set to first(sl, 0, 0, 5)
end

script, pressure plate press animate, sl, begin
  frame set to last(sl, 0, 0, 5)
end

script, prickly lettuce animate, sl, begin
  apply frame set(sl, 0)
  variable(pic)
  pic := get pic(sl)
  variable(fx)
  fx := get force x(sl)
  if(fx <> 0) then(
    oscillate frame(pic, 0, 1, 2)
  )
  #damage animate(sl, 0, 3, 4, 5)
end

script, prickly lettuce shoot animate, sl, begin
  frame to last(get pic(sl), 2, 5, 2)
end
 
script, inverse larkspur animate, sl, begin
  variable(pic, fx, fy, fl)
  pic := get pic(sl)
  if(get ai toggle(sl)) then(
    #Inverse
    if(not(sprite is vert flipped(pic))) then(
      vert flip sprite(pic, true)
      realign slice(pic, edge:center, edge:top, edge:center, edge:top)
    )
    fl := get touching ceiling(sl)
  )else(
    #Normal
    if(sprite is vert flipped(pic)) then(
      vert flip sprite(pic, false)
      realign slice(pic, edge:center, edge:bottom, edge:center, edge:bottom)
    )
    fl := get touching floor(sl)
  )
  fx := get force x(sl)
  fy := get force y(sl)
  if(fl) then(
    if(fx <> 0) then(
      apply frame set(sl, 0, 1)
      oscillate frame(pic, 0, 2, 2)
    )else(
      apply frame set(sl, 0, 0)
      set sprite frame(pic, 0)
    )
  )else(
    apply frame set(sl, 0, 2)
    if(abs(fy) <= 4 || get age(sl) <= 4) then(
      set sprite frame(pic, 1)
    )else(
      set sprite frame(pic, 0)
    )
  )
  damage animate(sl, 0, 1, 1, 2)
end

script, green knight animate, sl, begin
  variable(pic)
  apply frame set(sl, 0)
  pic := get pic(sl)
  if(get touching floor(sl)) then(
    if(get force x(sl) <> 0) then(
      oscillate frame(pic, 0, 2, 2)
    )else(
      set sprite frame(pic, 1)
    )
  )else(
    apply frame set(sl, 0, 4)
    if(get age(sl) <= 1) then(
      set sprite frame(pic, 0)
    )else(
      frame to last(pic, 0, 2, 4)
    )
  )
  if(not(get guard bit(sl))) then(
    damage animate(sl, 0, 0, 0, 2, 5, 3)
  )
end

script, green knight react animate, sl, begin
  variable(pic, age)
  pic := get pic(sl)
  age := get age(sl)
  if(age < second) then(
    apply frame set(sl, 0, 1)
    if (age == 0) then(
      set sprite frame(pic, 0)
    )else(
      frame to last(pic, 0, 2, 4)
    )
  )else(
    apply frame set(sl, 0, 2)
    set sprite frame(pic, 0)
  )
  if(not(get guard bit(sl))) then(
    damage animate(sl, 0, 0, 0, 2, 5, 3)
  )
end

script, necros root animate, sl, begin
  variable(fx)
  fx := get force x(sl)
  if(get touching floor(sl)) then(
    if(fx <> 0) then(
      if(sign(fx) == get direction(sl)) then(
        # Forward
        loop frame set(sl, 0, 1, 4, 3)
      )else(
        # backwards
        reverse loop frame set(sl, 0, 1, 4, 3)
      )
    )
  )
end

script, necros root attack animate, sl, begin
  if(get age(sl) > second * 6 / 4) then(
    # Close mouth
    frame set to first(sl, 0, 5, 8, 4)
  )else(
    # Open mouth
    frame set to last(sl, 0, 5, 8, 4)
  )
end

script, necros root blast animate, sl, begin
  variable(age, pic)
  age := get age(sl)
  pic := get pic(sl)
  if(age == 8) then(
    set sprite frame(pic, 0)
  )else if(age > 8) then(
    apply frame set(sl, 0, 1)
    frame to last(pic, 0, 7)
  )else(
    apply frame set(sl, 0, 0)
    frame to last(pic, 0, 7)
  )
end

script, heli succulent animate, sl, begin
  variable(pic, age)
  pic := get pic(sl)
  loop frame(pic, 0, 2, 1)
end

script, heli succulent attack animate, sl, begin
  variable(pic, age)
  pic := get pic(sl)
  loop frame(pic, 3, 5, 1)
end

script, bullrusher animate, sl, begin
  apply frame set(sl, 0, 0)
  death dissolve(sl, dissolve:melt)
end

script, bullrusher turnabout animate, sl, begin
  apply frame set(sl, 0, 1)
end

script, set bullrusher head animate, cb, begin
  variable(sl)
  sl := lookup slice(sli:bullrusher head, active)
  if(sl) then(
    set animation callback(sl, cb)
  )
end

script, bullrusher head animate, sl, begin
  clone damage tick(sl)
  if(get ai toggle(sl)) then(
    frame set to first(sl, 0, 0, 4, 2)
  )else(
    frame set to last(sl, 0, 0, 4, 2)
  )
end

script, bullrusher head turnabout animate, sl, begin
  clone damage tick(sl)
  apply frame set(sl, 1, 3)
end

script, bullrusher leg animate, sl, begin
  clone damage tick(sl)
  variable(a)
  a := get attached to(sl)
  if(a) then(
    if(get force x(a) <> 0) then(
      loop frame set(sl, 0, 0, 6, 2)
      variable(fr)
      fr := get current frame set(sl)
      if(fr == 0 || fr == 4) then(
        cycle sound(sfx:bullstomp1, sfx:bullstomp4, @cycle:bullstomp)
      )
    )
  )
  death dissolve(sl, dissolve:melt)
end

script, bullrusher backleg animate, sl, begin
  clone damage tick(sl)
  variable(a2)
  a2 := get secondary attach(sl)
  if(a2) then(
    variable(fr)
    fr := get current frame set(a2)
    apply frame set(sl, 0, ((fr + 3) ,mod, 7))
  )
  death dissolve(sl, dissolve:melt)
end

script, bullrusher eye animate, sl, begin
  
end

script, bullrusher puff animate, sl, begin
  if(frame to last(get pic(sl), 0, 7, 3)) then(set remove me(sl, true))
end

script, bullrusher dust animate, sl, begin
  if(random percent(50)) then(
    if(frame to last(get pic(sl), 0, 7, 1)) then(set remove me(sl, true))
  )
end

script, bullrusher quill animate, sl, begin
  if(random percent(80)) then(
    variable(fr)
    fr := get current frame set(sl, 0)
    if(fr >= 5 && fr <= 7) then(
      frame set to first(sl, 0, 0, 7, 20)
    )else(
      if(fr == 0 || fr == 8) then(
        if(random percent(10)) then(ai toggle(sl))
      )
      if(get ai toggle(sl)) then(
        oscillate frame set(sl, 0, 8, 11, 4)
      )else(
        oscillate frame set(sl, 0, 0, 4, 4)
      )
    )
  )
end

script, bullrusher spike animate, sl, begin
  variable(fr)
  fr := get current frame set(sl, 0)
  if(fr < 7) then(
    frame set to last(sl, 0, 0, 7, 4)
    set slice height(sl, 4 + fr * 5)
  )else(
    oscillate frame set(sl, 0, 7, 9)
  )
end

script, rock dropper animate, sl, begin
  loop frame(get pic(sl), 0, 7, 2)
end

script, bullflier animate, sl, begin
  if(get ai toggle(sl)) then(
    frame set to first(sl, 0, 0, 4, 2)
  )else(
    frame set to last(sl, 0, 0, 4, 2)
  )
  death dissolve(sl, dissolve:vapourise)
end

script, bullflier belch animate, sl, begin
  frame set to last(sl, 1, 0, 2, 3)
end

script, bullflier crash animate, sl, begin
  apply frame set(sl, 1, 3)
end

script, bullflier flagellum animate, sl, begin
  loop frame set(sl, 0, 0, 10, 1)
end

script, bullflier belchgas animate, sl, begin
  if(frame to last(get pic(sl), 0, 7, 2)) then(set remove me(sl, true))
end

script, corpse eater dormant animate, sl, begin
  apply frame set(sl, 0, 0)
  variable(pic)
  pic := get pic(sl)
  if(alternate(sl, second)) then(
    set sprite frame(pic, 0)
  )else(
    set sprite frame(pic, 1)
  )
end

script, corpse eater animate, sl, begin
  apply frame set(sl, 0, 0)
  variable(pic)
  pic := get pic(sl)
  if(get force x(sl) <> 0) then(
    oscillate frame(pic, 3, 5, 2)
  )else(
    set sprite frame(pic, 2)
  )
  death dissolve(sl, dissolve:shrink)
end

script, corpse eater stunned animate, sl, begin
  apply frame set(sl, 0, 1)
  variable(pic)
  pic := get pic(sl)
  oscillate frame(pic, 0, 4, 1)
  flash palette(sl, true)
end

script, bursting cactus animate, sl, begin
  variable(fx, pic)
  pic := get pic(sl)
  fx := get force x(sl)
  if(fx <> 0) then(
    oscillate frame(pic, 0, 2, 2)
  )
  damage animate(sl, 0, 3, 3, 4)
end

script, bursting cactus pop animate, sl, begin
  variable(pic, age)
  pic := get pic(sl)
  age := get age(sl)
  dissolve sprite(pic, dissolve:shrink, 100, 50 + (50 / second * age), true, true)
end

script, bursting cactus spine animate, sl, begin
  if(random percent(25)) then(
    set oscillate anim(sl, random(0, 1))
    oscillate frame(get pic(sl), 0, 7, 0)
  )
end


script, least frogmuculus animate, sl, begin
  variable(pic)
  pic := get pic(sl)
  if(get touching floor(sl)) then(
    if(get crouching(sl)) then(
      # Crouching
      set sprite frame(pic, 3)
    )else(
      # Standing
      oscillate frame(pic, 0, 2, 2)
    )
  )else(
    # Jumping
    set sprite frame(pic, 4)
  )
end

script, omen caster animate, sl, begin
  variable(pic)
  pic := get pic(sl)
  apply frame set(sl, 0, 0)
  loop frame(pic, 0, 1, 1)
end

script, omen caster throw animate, sl, begin
  variable(pic)
  pic := get pic(sl)
  apply frame set(sl, 0, 0)
  frame to last(pic, 2, 6, 3)
end

script, omen caster jump animate, sl, begin
  variable(pic)
  pic := get pic(sl)
  apply frame set(sl, 0, 1)
  if(get force y(sl) < 0) then(
    set sprite frame(pic, 0)
  )else(
    set sprite frame(pic, 1)
  )
end

script, omen caster token animate, sl, begin
  loop frame(get pic(sl), 0, 7, 1)
end

script, carrot diablo walk animate, sl, begin
  if(get guard bit(sl)) then(
    apply frame set(sl, 0, 5)
    exit script
  )
  variable(fx, d)
  fx := get force x(sl)
  d := get direction(sl)
  if(fx <> 0) then(
    if(d == sign(fx)) then(
      loop frame set(sl, 0, 0, 4, 2)
    )else(
      reverse loop frame set(sl, 0, 0, 4, 2)
    )
  )
end

script, carrot diablo charge animate, sl, begin
  frame set to last(sl, 0, 5, 8, 4)
end

script, carrot diablo attack animate, sl, begin
  frame set to last(sl, 0, 9, 13, 2)
end

script, flame vine animate, sl, begin
  variable(pic)
  pic := get pic(sl)
  death dissolve(sl, dissolve:melt)
  if(get attack phase(sl) > 0) then(
    frame to last(pic, 3, 7, 3)
    exit script
  )
  variable(fx)
  fx := get force x(sl)
  if(fx <> 0) then(
    oscillate frame(pic, 0, 2, 2)
  )
end

script, green pixy animate, sl, begin
  variable(pic)
  pic := get pic(sl)
  oscillate frame(pic, 0, 5, 0)
end

script, green pixy body animate, sl, begin
  variable(pic, a)
  a := get attached to(sl)
  pic := get pic(sl)
  if(get touching floor(a)) then(
    oscillate frame(pic, 4, 5, 3)
  )else if(get direction(a) == sign(get force x(a))) then(
    frame to last(pic, 3, 3, 1)
  )else(
    oscillate frame(pic, 0, 2, 1)
  )
end

script, colobanthus animate, sl, begin
  variable(pic)
  pic := get pic(sl)
  oscillate frame(pic, 0, 1, 1)
end