# Walktall.hss
#
# This example script shows how to make tall walkabouts in the OHRRPGCE by replacing hero
# and NPC walkabout slices with battle sprites. This requires An OHRRPGCE Nightly Wip build
# from at least August 5 2011 (Or if you are reading this in the future, any stable release
# starting with "Alectormancy" will be fine.) (If you are reading this in the even more
# distant future, there might already be a built-in way to to tall walkabouts with no scripting)
#
# To make the heroes and NPCs overlap each other correctly you should set
# "Walkabout Layering: Together" in the general map data editor (this is the
# default for new maps)

include, plotscr.hsd

plotscript, map autorun, begin
  embiggen heroes
  embiggen NPCs
end

script, embiggen heroes, begin
  variable(hero, sl)
  for(hero, 0, 3) do(
    if(hero by rank(hero) >= 0) then(
      # hero exists
      sl := get hero slice(hero)
      embiggen walkabout slice(sl)
    )
  )
end

script, embiggen NPcs, begin
  variable(npc, sl)
  for(npc, -1, -300, -1) do(
    if(get NPC id(npc) >= 0) then(
      # this NPC exists
      sl := get NPC slice(npc)
      embiggen walkabout slice(sl)
    )
  )
end

script, embiggen walkabout slice, sl, begin
  variable(pic sl, pic num)
  if(sl) then(
    pic sl := lookup slice(sl:walkabout sprite component, sl)
    pic num := get sprite set number(pic sl)
    replace hero sprite(pic sl, pic num)
  )
end