Example InnoSetup script
Jump to navigation
Jump to search
This is an example InnoSetup script that you can customize for your own use.
; This script is used by Inno Setup to create a Windows Installer.
; You can use this as an example for packaging your own game.
; see http://www.jrsoftware.org/isinfo.php to download Inno Setup
[Setup]
AppName=My Game Name
AppVerName=My Game Name 2008.04.14.0
VersionInfoVersion=2008.04.14.0
AppPublisher=My Company Name or My Own Name
AppPublisherURL=http://my.web.site.ext/wherever/
AppSupportURL=http://my.web.site.ext/wherever/support.html
AppUpdatesURL=http://my.web.site.ext/wherever/updates.html
AppReadmeFile={app}\README.txt
DefaultDirName={pf}\Games By Me\My Game Name
DefaultGroupName=My Game Name
DisableProgramGroupPage=yes
AllowNoIcons=yes
AllowUNCPath=no
LicenseFile=LICENSE-binary.txt
InfoAfterFile=README.txt
OutputBaseFilename=my-game-name
Compression=bzip
SolidCompression=yes
ChangesAssociations=no
UninstallDisplayIcon={app}\mygame.ico
[Languages]
Name: "eng"; MessagesFile: "compiler:Default.isl"
[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"
[Files]
Source: "game.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "SDL.dll"; DestDir: "{app}"; Flags: ignoreversion
Source: "SDL_mixer.dll"; DestDir: "{app}"; Flags: ignoreversion
Source: "mygame.rpg"; DestDir: "{app}"; Flags: ignoreversion
Source: "mygame.ico"; DestDir: "{app}"; Flags: ignoreversion
Source: "README.txt"; DestDir: "{app}"; Flags: ignoreversion
Source: "LICENSE-binary.txt"; DestDir: "{app}"; Flags: ignoreversion
; NOTE: Don't use "Flags: ignoreversion" on any shared system files
; NOTE: but this is okay for SDL.dll and SDL_mixer.dll because they go into the app directory.
[Icons]
Name: "{group}\My Game Name"; Filename: "{app}\game.exe"; Flags: closeonexit
Name: "{group}\My Game Name (fullscreen)"; Filename: "{app}\game.exe"; Parameters: "-f"; Flags: closeonexit
Name: "{userdesktop}\My Game Name"; Filename: "{app}\game.exe"; Flags: closeonexit; Tasks: desktopicon